root/trunk/acinclude.m4

dnl AM_PATH_CHECK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
dnl Test for check, and define WBXML_CFLAGS and WBXML_LIBS
dnl

AC_DEFUN([AM_PATH_WBXML],
[
  AC_ARG_WITH(wbxml,
  [  --with-wbxml=PATH       prefix where wbxml is installed [default=auto]])
 
  min_check_version=ifelse([$1], ,0.9.0,$1)

  AC_MSG_CHECKING(for wbxml - version >= $min_check_version)

  if test x$with_wbxml = xno; then
    AC_MSG_RESULT(disabled)
  else
    if test "x$with_wbxml" != x -a "x$with_wbxml" != "xyes"; then
      WBXML_CFLAGS="-I$with_wbxml/include"
      WBXML_LIBS="-L$with_wbxml/lib -lwbxml2"
    else
      WBXML_CFLAGS="-I/usr/include/wbxml2"
      WBXML_LIBS="-L${libdir} -lwbxml2"
    fi

    ac_save_CFLAGS="$CFLAGS"
    ac_save_LIBS="$LIBS"

    CFLAGS="$WBXML_CFLAGS $CFLAGS"
    LIBS="$WBXML_LIBS $LIBS"

        AC_TRY_COMPILE([#include <wbxml.h>],[WBXMLConvXML2WBXMLParams w; w.wbxml_version = WBXML_VERSION_11 ],AC_MSG_RESULT(yes);LIBWBXML=yes,AC_MSG_RESULT(no);LIBWBXML=no)
        
        if test "x${LIBWBXML}" = "xno"; then
           echo "To enable WBXML communication (for e.g. cell phones) you must have version 0.8.1 or later of libwbxml2."
        else
                AC_DEFINE_UNQUOTED(ENABLE_WBXML, 1, Defined if the correct libwbxml2 version exists.)
                AC_DEFINE_UNQUOTED(WBXML_LIBS, " -lwbxml",[wbxml])
                AC_SUBST(WBXML_LIBS)
        fi
        
        AM_CONDITIONAL(ENABLE_WBXML, test x$LIBWBXML = xyes)
        
    CFLAGS="$ac_save_CFLAGS"
    LIBS="$ac_save_LIBS"

    AC_SUBST(WBXML_CFLAGS)
    AC_SUBST(WBXML_LIBS)

        echo "checking WBXML_CFLAGS... $WBXML_CFLAGS" 
        echo "checking WBXML_LIBS... $WBXML_LIBS"

  fi
])

dnl AM_PATH_CHECK([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
dnl Test for check, and define CHECK_CFLAGS and CHECK_LIBS
dnl

AC_DEFUN([AM_PATH_CHECK],
[
  AC_ARG_WITH(check,
  [  --with-check=PATH       prefix where check is installed [default=auto]])
 
  min_check_version=ifelse([$1], ,0.8.2,$1)

  AC_MSG_CHECKING(for check - version >= $min_check_version)

  if test x$with_check = xno; then
    AC_MSG_RESULT(disabled)
    ifelse([$3], , AC_MSG_ERROR([disabling check is not supported]), [$3])
  else
    if test "x$with_check" != x; then
      CHECK_CFLAGS="-I$with_check/include"
      CHECK_LIBS="-L$with_check/lib -lcheck"
    else
      CHECK_CFLAGS=""
      CHECK_LIBS="-lcheck"
    fi

    ac_save_CFLAGS="$CFLAGS"
    ac_save_LIBS="$LIBS"

    CFLAGS="$CFLAGS $CHECK_CFLAGS"
    LIBS="$CHECK_LIBS $LIBS"

    rm -f conf.check-test
    AC_TRY_RUN([
#include <stdio.h>
#include <stdlib.h>

#include <check.h>

int main ()
{
  int major, minor, micro;
  char *tmp_version;

  system ("touch conf.check-test");

  /* HP/UX 9 (%@#!) writes to sscanf strings */
  tmp_version = strdup("$min_check_version");
  if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
     printf("%s, bad version string\n", "$min_check_version");
     return 1;
   }
    
  if ((CHECK_MAJOR_VERSION != check_major_version) ||
      (CHECK_MINOR_VERSION != check_minor_version) ||
      (CHECK_MICRO_VERSION != check_micro_version))
    {
      printf("\n*** The check header file (version %d.%d.%d) does not match\n",
             CHECK_MAJOR_VERSION, CHECK_MINOR_VERSION, CHECK_MICRO_VERSION);
      printf("*** the check library (version %d.%d.%d).\n",
             check_major_version, check_minor_version, check_micro_version);
      return 1;
    }

  if ((check_major_version > major) ||
      ((check_major_version == major) && (check_minor_version > minor)) ||
      ((check_major_version == major) && (check_minor_version == minor) && (check_micro_version >= micro)))
    {
      return 0;
    }
  else
    {
      printf("\n*** An old version of check (%d.%d.%d) was found.\n",
             check_major_version, check_minor_version, check_micro_version);
      printf("*** You need a version of check being at least %d.%d.%d.\n", major, minor, micro);
      printf("***\n"); 
      printf("*** If you have already installed a sufficiently new version, this error\n");
      printf("*** probably means that the wrong copy of the check library and header\n");
      printf("*** file is being found. Rerun configure with the --with-check=PATH option\n");
      printf("*** to specify the prefix where the correct version was installed.\n");
    }

  return 1;
}
],, no_check=yes, [echo $ac_n "cross compiling; assumed OK... $ac_c"])

    CFLAGS="$ac_save_CFLAGS"
    LIBS="$ac_save_LIBS"

    if test "x$no_check" = x ; then
      AC_MSG_RESULT(yes)
      ifelse([$2], , :, [$2])
    else
      AC_MSG_RESULT(no)
      if test -f conf.check-test ; then
        :
      else
        echo "*** Could not run check test program, checking why..."
        CFLAGS="$CFLAGS $CHECK_CFLAGS"
        LIBS="$CHECK_LIBS $LIBS"
        AC_TRY_LINK([
#include <stdio.h>
#include <stdlib.h>

#include <check.h>
], ,  [ echo "*** The test program compiled, but did not run. This usually means"
        echo "*** that the run-time linker is not finding check. You'll need to set your"
        echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
        echo "*** to the installed location  Also, make sure you have run ldconfig if that"
        echo "*** is required on your system"
        echo "***"
        echo "*** If you have an old version installed, it is best to remove it, although"
        echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],
      [ echo "*** The test program failed to compile or link. See the file config.log for"
        echo "*** the exact error that occured." ])
      
        CFLAGS="$ac_save_CFLAGS"
        LIBS="$ac_save_LIBS"
      fi

      CHECK_CFLAGS=""
      CHECK_LIBS=""

      rm -f conf.check-test
      ifelse([$3], , AC_MSG_ERROR([check not found]), [$3])
    fi

    AC_SUBST(CHECK_CFLAGS)
    AC_SUBST(CHECK_LIBS)

    rm -f conf.check-test

  fi
])

AC_DEFUN([AM_PATH_OPENOBEX], [
        if (test "${prefix}" = "NONE"); then
                openobex_prefix=${ac_default_prefix}
        else
                openobex_prefix=${prefix}
        fi

        AC_ARG_WITH(openobex, AC_HELP_STRING([--with-openobex=DIR], [OpenOBEX library is installed in DIR]), [
                if (test "${withval}" != "yes"); then
                        openobex_prefix=${withval}
                fi
        ])

        ac_save_CPPFLAGS=$CPPFLAGS
        ac_save_LDFLAGS=$LDFLAGS

        OPENOBEX_CFLAGS=""
        test -d "${openobex_prefix}/include" && OPENOBEX_CFLAGS="$OPENOBEX_CFLAGS -I${openobex_prefix}/include"

        CPPFLAGS="$CPPFLAGS $OPENOBEX_CFLAGS"
        AC_CHECK_HEADER(openobex/obex.h,, AC_MSG_ERROR(OpenOBEX header files not found))

        OPENOBEX_LIBS=""
        if (test "${ac_default_prefix}" = "${openobex_prefix}"); then
                test -d "${libdir}" && OPENOBEX_LIBS="$OPENOBEX_LIBS -L${libdir}"
        else
                test -d "${openobex_prefix}/lib64" && OPENOBEX_LIBS="$OPENOBEX_LIBS -L${openobex_prefix}/lib64"
                test -d "${openobex_prefix}/lib" && OPENOBEX_LIBS="$OPENOBEX_LIBS -L${openobex_prefix}/lib"
        fi

        LDFLAGS="$LDFLAGS $OPENOBEX_LIBS"
        AC_CHECK_LIB(openobex, OBEX_Init, OPENOBEX_LIBS="$OPENOBEX_LIBS -lopenobex", AC_MSG_ERROR(OpenOBEX library not found))

        CPPFLAGS=$ac_save_CPPFLAGS
        LDFLAGS=$ac_save_LDFLAGS

        AC_SUBST(OPENOBEX_CFLAGS)
        AC_SUBST(OPENOBEX_LIBS)
])